Git一键静默安装脚本
<pre><code class="language-bash">@echo off
title Git一键静默安装脚本
mode con cols=60 lines=14
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul&&goto UACAdmin||goto UACPrompt
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
:UACAdmin
echo.正在安装Git客户端...
echo %PROCESSOR_ARCHITECTURE%|find "64">nul&&call :x64||call :x86
reg add HKEY_CURRENT_USER\Software\TortoiseGit /v "LanguageID" /t REG_DWORD /d 2052 /f
reg add HKEY_CURRENT_USER\Software\TortoiseGit /v "MSysGit" /t REG_SZ /d "C:\Program Files\Git\bin" /f
setx HOME "%USERPROFILE%"
set HOME=%USERPROFILE%
taskkill /f /im explorer.exe >nul 2>nul
start "" explorer
::自动配置提交用户名及email
"C:\Program Files\Git\cmd\git.exe" config --global user.name "%username%"
"C:\Program Files\Git\cmd\git.exe" config --global user.email "%username%@paxsz.com"
::公钥自助生成
choice /m "是否需要生成Git公钥及秘钥"
if %errorlevel% == 1 (
echo 如果不需要设置私钥密码，连续按三次回车即可
"C:\Program Files\Git\usr\bin\ssh-keygen.exe" -f "%USERPROFILE%\.ssh\id_rsa" -C %username%
echo 秘钥生成完毕。
start "" %USERPROFILE%\.ssh
)
timeout 5
exit
:x86
"\\172.16.2.166\share\tools\Git-2.22.0-32-bit.exe" /VERYSILENT /SP- /loadinf="\\172.16.2.166\share\tools\Git-install.inf"
msiexec /package "\\172.16.2.166\share\tools\TortoiseGit-2.8.0.0-32bit.msi" /quiet /norestart
echo.正在安装Git客户端汉化包...
msiexec /package "\\plm2.paxsz.com\Share\tools\TortoiseGit-LanguagePack-2.8.0.0-32bit-zh_CN.msi" /quiet /norestart
goto :eof
:x64
"\\plm2.paxsz.com\Share\tools\Git-2.22.0-64-bit.exe" /VERYSILENT /SP- /loadinf="\\172.16.2.166\share\tools\Git-install.inf"
msiexec /package "\\plm2.paxsz.com\Share\tools\TortoiseGit-2.8.0.0-64bit.msi" /quiet /norestart
echo.正在安装Git客户端汉化包...
msiexec /package "\\plm2.paxsz.com\Share\tools\TortoiseGit-LanguagePack-2.8.0.0-64bit-zh_CN.msi" /quiet /norestart
goto :eof</code></pre>