批处理管理员权限执行
<pre><code class="language-bash">@echo off
title SVN一键静默安装脚本
mode con cols=60 lines=14
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul&&goto UACAdmin||goto UACPrompt
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
:UACAdmin
echo.正在安装SVN客户端...
echo %PROCESSOR_ARCHITECTURE%|find "64">nul&&call :x64||call :x86
reg add HKEY_CURRENT_USER\Software\TortoiseSVN /v "LanguageID" /t REG_DWORD /d 2052 /f
taskkill /f /im explorer.exe >nul 2>nul
start "" explorer
timeout 5
exit
:x86
msiexec /package "\\plm2.paxsz.com\share\tools\TortoiseSVN-1.12.0.28568-win32-svn-1.12.0.msi" /quiet /norestart
cls
echo.正在安装SVN客户端汉化包...
msiexec /package "\\plm2.paxsz.com\share\tools\LanguagePack_1.12.0.28568-win32-zh_CN.msi" /quiet /norestart
goto :eof
:x64
msiexec /package "\\plm2.paxsz.com\share\tools\TortoiseSVN-1.12.0.28568-x64-svn-1.12.0.msi" /quiet /norestart
cls
echo.正在安装SVN客户端汉化包...
msiexec /package "\\plm2.paxsz.com\share\tools\LanguagePack_1.12.0.28568-x64-zh_CN.msi" /quiet /norestart
goto :eof</code></pre>