易语言代码示例
<p>全局变量声明：</p>
<pre><code>.版本 2
.支持库 EXMLParser
.全局变量 控雀API网址, 文本型
.全局变量 控雀控制码, 文本型
.全局变量 控雀远程参数数据, XML树
</code></pre>
<p>程序集声明：</p>
<pre><code>.版本 2
.支持库 internet
.支持库 EXMLParser
.程序集 控雀
.子程序 加载控雀远程参数, , 公开
.局部变量 网址, 文本型
.局部变量 XML文本, 文本型
.局部变量 参数及, 文本型, , &quot;0&quot;
' 面板API
控雀API网址 ＝ “http://api.coocheck.com/check?panel=pn-xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxxx&amp;code=”
' 控雀控制码，通常由用户输入提供
网址 ＝ 控雀API网址 ＋ 控雀控制码 ＋ “&amp;type=xml&amp;encode=gb”
XML文本 ＝ 到文本 (HTTP读文件 (网址))
' 调试输出 (“CooCheck API 网址：” ＋ 网址)
' 调试输出 (“CooCheck API 返回：” ＋ XML文本)
控雀远程参数数据.导入 (到字节集 (XML文本))
.子程序 读取控雀远程参数, 文本型, 公开
.参数 键名, 文本型
.参数 默认值, 文本型
.局部变量 参数索引, 整数型
.变量循环首 (1, 控雀远程参数数据.取子节点个数 (“root”, ), 1, 参数索引)
.如果 (控雀远程参数数据.取属性值文本 (“root/@” ＋ 到文本 (参数索引), “name”, ) ＝ 键名)
返回 (控雀远程参数数据.取节点值文本 (“root/@” ＋ 到文本 (参数索引), ))
.否则
.如果结束
.变量循环尾 ()
返回 (默认值)</code></pre>
<p>拉取远程参数时，通过<code>读取控雀远程参数</code>方式，远程参数数据会保存到全局变量<code>控雀远程参数数据</code>。
读取远程参数时，通过<code>读取控雀远程参数(键名, 默认值)</code>方式读取指定键名的参数；特殊情况下我们会担心指定键名的参数获取失败而影响脚本运行，比如发布新面板时候不慎删除某个有用的键名，而默认值参数的作用是发现键名参数不存在时，以默认值值作为参数值返回。</p>
<pre><code>' 返回key为submited_at的参数值，如果不存在该参数，则返回“0”
调试输出 (“submited_at：” ＋ 读取控雀远程参数 (“submited_at”, “0”))
' 返回key为key1的参数值，如果不存在该参数，则返回“123”
调试输出 (“key1：” ＋ 读取控雀远程参数 (“key1”, “123”))</code></pre>
<p>如果脚本有界面，希望获取到的新参数同步修改界面，可以把新参数回写到界面。</p>
<pre><code>' 返回key为key1的参数值，如果不存在该参数，则返回 编辑框1.内容
' 最终返回的内容又更新到 编辑框1.内容
编辑框1.内容 ＝ 读取控雀远程参数 (“key1”, 编辑框1.内容)
' 返回key为key2的参数值，如果不存在该参数，则返回 滑块条1.位置
' 最终返回的内容又更新到 滑块条1.位置
滑块条1.位置 ＝ 到整数 (读取控雀远程参数 (“key2”, 到文本 (滑块条1.位置)))</code></pre>